!===============================================================================
! PROGRAM:          MMSM 1 Lab No 11 (Ansys Exercise 9)
! PROJEKT:          Ansys Exercise to perform 2D Contact Analysis
! TASK:             Top BODY 1 with curved surface is moving downwards and contacting
!                   against BODY 2 with plane surface
! AUTHOR:           Simon
! LAST CHANGES:     2011.01.28
! 
! COMPUTER:         
! OPERATING SYSTEM: 
! ANSYS Version:    License: Teaching Adv.: 13.0
! 
! CALL:             /input,FE-Exercise9-Kontakt.inp
! 
!===============================================================================

!=== Beginning
finish              ! Stops all modules (preprocessor, solution, postprocessor)
/clear              ! Start a new analysis, delete the old database (file.db)

/PLOPTS, INFO, AUTO ! Good old contour labeling style


!===============================================================================
!  Parameters (lenght in mm, forces in N => stiffnesses and stresses in N/mm)
!===============================================================================

!--- Zur Geometrie
H1     =     100.0			! Height (y) of body 1
B1     =     220.0			! Length (x)
HC     =     100.0			! Height of Curve (y)

H2     =     200.0			! Height (y) of body 2
B2     =     500.0			! Length (x)

Delta  =       3.0			! Initial contact gap
Thickn =     100.0			! Thickness of bodies

MeshParam1 =    1			! Globale Netzgrobheit 1(fein)..10(grob), body 1
MeshParam2 =    1			! Globale Netzgrobheit 1(fein)..10(grob), body 2

!--- Zur Last/Verschiebungslast
Versch   =   -80.0         		! (-40!) Displacement load (alternative to force)

!--- Zum Werkstoff
Young1 = 210000.0			! Young's modulus of the plates material
Poiss1 =      0.3			! Poisson's ratio of the plates material
Young2 =      1.0			! Young's modulus of the plates material
Poiss2 =      0.49			! Poisson's ratio of the plates material

!--- Zum Werkstoff
mu_wert = 0.0				! Reibwert

!===============================================================================
! A. Preprocessor (Setting up the model)
!===============================================================================
/prep7					! Switch to the preprocessor modul


!=== A.1 Build the geometry by means of bottom-up method

!=== Create body 1
k,1,-B1/2, 0.0, 0.0		! Create Keypoints
k,2,-B1/2,  H1, 0.0
k,3, B1/2,  H1, 0.0
k,4, B1/2, 0.0, 0.0
k,5,  0.0, -HC, 0.0		! Keypoint am Maximum

lstr,1,2			! Connect keypoints to craete line
lstr,2,3
lstr,3,4
larc,4,1,5			! Create Arch

al,all				! Create area by all selected lines (1, 2, 3, 4)


!=== Create body 2
dY = -HC - Delta -H2

k,6,-B2/2, dY, 0.0		! Create Keypoints
k,7,-B2/2, H2 + dY, 0.0
k,8, B2/2, H2 + dY, 0.0
k,9, B2/2, dY, 0.0

lstr, 6, 7			! Connect keypoints to craete line
lstr, 7, 8
lstr, 8, 9
lstr, 9, 6

al,5,6,7,8			! Create area by all selected lines (1, 2, 3, 4)
aplot				! Plot areas


!=== A.2 Meshing
et,1,plane42			! Define element type
keyopt,1,3,3			! Sets key option 3 (of elem type 1) to 3 (plane stress with thickn)

smrtsize, MeshParam1		! Globale Netzfeinheit 1(fein)..10(grob)
mat,1
amesh, 1			! Meshing areas with this number

smrtsize, MeshParam2		! Globale Netzfeinheit 1(fein)..10(grob)
mat,2
amesh, 2			! Meshing areas with this number

eplot				! Plot elements

!=== A.3 Material Properties
!--- Define real constants
r,1,Thickn			! Define thickness of the beam into real set number 1

!--- Define material properties for mat type 1
mp,ex,1,Young1			! Define Young's modulus for material No 1
mp,prxy,1,Poiss1		! Define Poisson's ratio for material No 1

!--- Define material properties for mat type 2
mp,ex,2,Young2			! Define Young's modulus
mp,prxy,2,Poiss2		! Define Poisson's ratio


!=== A.4 Apply Load and Boundary Conditions

!--- Applying the load as a displacement on top body 1
nsel,s,loc,y,H1			! Select nodes
d,all,ux,0.0			! Set displacement
d,all,uy,Versch			! Set displacement
allsel				! Select all entities 

!--- Displacement BC body 2
nsel,s,loc,y,dY			! Select nodes
d,all,ux,0.0			! Set displacement
d,all,uy,0.0			! Set displacement
allsel				! Select all entities 

!===============================================================================
! Contact Definition
!===============================================================================
et,3,conta171			! 2D-2Node-S2S-Kontaktelement
keyopt,3,2,1			! Keyopt(2) = 1 (Penalty); 4 (Lagrange)
et,4,targe169			! 2D-S2S-Targetelement

mp,mu,3,mu_wert			! Reibwert
!r,3,,,rFKN,rFTOLN,rICONT	! Real numbers 1 bis 6;	(5=rICONT)
!rmore,,,rTAUMAX		! weitere Real numbers 7 - 12
mat,3				! Material-Zeiger auf Material #3 umschalten
real,3				! Elementtyp-Zeiger auf El.-Typ #3 umschalten

!--- Contact-Seite, body 1, oben
lsel,s,line,,4
nsll,s,1
type,3				! 2 = Contact Elemente
esurf
allsel

!--- Target-Seite, body 2, unten
lsel,s,line,,6
nsll,s,1
type,4				! 3 = Target Elemente
esurf
allsel


!===============================================================================
!B. Solution
!===============================================================================
/solu				! Switch to the solution module
antype,0			! Select the static analysis type 

!--- Optionale Loesungsparameter
!nlgeom,on			! nur fuer grosse Verformungen
!cnvtol,f,,0.01			! Konvergenzwerte setzen
nsub,100,1000,100		! Anz. Schritte: initial, max., min. 
outres,all,-25			! -10 =	10 aequidist Substeps abspeichern, default: only last

solve				! Solve current load step

!===============================================================================
!C. Postprocessor
!===============================================================================
/post1				! Switch to the postprocessor module

!=== C.1 Contour plot: displacement u_y
/dscale, 1, 1.0			! Switch off auto scaling of deformed shape
/title,Displacements u_y in mm
plnsol, u, y, 2			! Contour plot of vertical displacements

!=== C.2 Contour plot: normal stress in y direction
/title,Eqv. Stress in MPa
plesol, s, eqv, 0		! Contour plot of vertical displacements

!=== C.3 Contour plot: Contact pressure
/title,Contact normal stress in MPa
plnsol,cont,pene