!===============================================================================
! ANSYS CLASSIC INPUT FILE
!===============================================================================
! PROGRAM:          	Zweischlag
! PROJEKT:		For MMSM-1, Computer Lab
! TASK:			2-Schlag zur Berechnung der nichtlineare 
!			Kraft-Verformungskennlinie
!
! AUTHOR:		(Simon, www.uni-ulm.de/uzwr)
! LAST CHANGES:		Feb. 2011
! 
! COMPUTER:		usim
! OPERATING SYSTEM:	Win7, 64bit
! ANSYS Version:	License: Academic Teaching Advanced, Version: 13.0
! 
! CALL:			/input,NLGeom2Schlag.inp
! 
!===============================================================================


!=== Beginning
FINISH			! Stops all modules (preprocessor, solution, postprocessor)
/CLEAR			! Clears an existing database to start a new analysis
/PLOPTS, INFO, AUTO	! Good old contour labeling style
/eshape,1		! Line elem plot with real tickness


!===============================================================================
!  Parameters (lenght in mm, forces in N => stiffnesses and stresses in N/mm)
!  Use them instead of numerical values!
!===============================================================================

L    =     100		! Length
k    =      10		! Steifigkeit
A    =       1		! Crossectional area
phi  =      30		! Angle

EMod =   k*L/A		! Aus k = EA/L
Nue  =       0.3	! Poisson's ratio

F    =    100.0		! (-80!) Force acting on full beam
V    =   -150.0		! Verschiebungslast fuer LS2
V0    =    50.0		! Initiale Verschiebungslast fuer LS1

nSteps = 100		! No. of fixed aequidist. substeps in nonlinear solution

!===============================================================================
! Preprocessor (Setting up the model)
!===============================================================================
/PREP7				! Switch to the preprocessor module


!=== Build the geometry: bottom-up method
phiInRad  =      phi*3.1415926/180
Lx = cos(phiInRad)*L
Ly = sin(phiInRad)*L

n,1,-Lx, 0.0, 0.0
n,2, Lx, 0.0, 0.0
n,3,0.0,  Ly, 0.0


!=== Meshing
!--- Assign the element type
ET, 1, LINK180			! Define the element type
e,1,3				! Direct generation of an element
e,2,3				! Direct generation of an element
eplot				! Plot elements


!=== Material Properties
!--- Define material properties
mp, ex, 1, EMod			! Define youngsMod's modulus for material no. 1
mp, prxy, 1, Nue		! Define poissonsRatio's ratio for material no. 1
!--- Define real constants
r,1,A				! Crossectional area

!=== Apply Load and Boundary Conditions
!--- Left side
d, 1, ux, 0.0		! Set this displacement BC
d, 1, uy, 0.0		! Set this displacement BC
allsel
!--- Right side
d, 2, ux, 0.0		! Set this displacement BC
d, 2, uy, 0.0		! Set this displacement BC
allsel

!--- LS1: Applying the load
!f, 3, fy, F			! Apply load on node
d, 3, uy, V0			! Alt.: Apply displ. load on node
lswrite,1

!--- LS2: Applying the load
!f, 3, fy, F			! Apply load on node
d, 3, uy, V			! Alt.: Apply displ. load on node
lswrite,2

!===============================================================================
! Solution
!===============================================================================
/solu				! Switch to the solution module

nlgeom,on			! Accounting for nonlinear 
lssolve,1

nsub,nSteps,nSteps*100,nSteps
outres,all,-nSteps		! -10 =	10 aequidist Substeps abspeichern, default: only last
lssolve,2			! Solve current load step


!===============================================================================
! Postprocessor
!===============================================================================
/post1                       ! Switch to the postprocessor module


!=== Options
/UDOC,, CNTR, RIGHT          ! Determines position of contour legend
/edge,,1
/gline,,0
/PBC, U,, 1
/PBC, F,, 2

!=== Get vertical force at moved node
nsel,s,node,,3
fsum
*GET, Force, FSUM, 0, ITEM, FY
allsel

!=== Contour plot normal stress in x direction
/contour,,9
/title,Displacement, vertical in mm; Force = %Force% N
plnsol, u, y, 2              ! Plot the deformed shape with normal stress in x

!=== Plot force-displacement curve
nsel,s,node,,3
*dim,Force,array,nSteps
*dim,Displ,array,nSteps
*do, step, 1, nsteps
   set,2,step
   fsum
   *GET, Kraft, FSUM, 0, ITEM, FY
   Force(step) = Kraft
   *GET, Weg, NODE, 3, U, Y
   Displ(step) = -Weg
*enddo
/title,Force-Displacement Curve
*VPLOT, Displ(1), Force(1)